X Shifterのスイッチユニットを自作しましたVer1.1 (使った部材やソースコードなど)

#include <ArduinoBLE.h>

/*バージョン*/
#define FW_VERSION "1.3.2"
/*接続用*/
#define ELINK_MACADDRESS "ef:e3:c8:09:96:eb" /*使用するElinkのMACアドレス*/
#define ELINK_LOCALNAME "Elin" /*現在未使用*/

#define PIN_SHIFT_UP    10
#define PIN_SHIFT_DOWN  11

#define SLEEP_ENTERTIME_SEARCH 20000 /*ms*/
#define SLEEP_ENTERTIME 600000 /*ms*/

/*BLE-UUID*/
#define ELINK_SERVICE_UUID "1523" /*Elink Service UUID*/
#define ELINK_CHARACTERISTIC_UUID "1524"  /*Elink 変速用Characteristic UUID*/
#define ELINK_READCHARACTERISTIC_UUID "1525" /*Elinkからの返信用Characteristic UUID*/

bool IsConnected = false;
byte sGearChangePacket[] = { 0x21, 0x00, 0x00, 0x00};
volatile bool sShiftChange = false;

BLEService sElinkService;
BLECharacteristic sElinkMotorCharacteristic;
BLECharacteristic sElinkReadCharacteristic;
BLEDevice sBLEPeripheral;
unsigned long sleepTimer;

bool Elink_Connect(BLEDevice peripheral) {
  int failCnt = 0;
  /*接続試行*/
  while (!peripheral.connect()) {
    failCnt++;
    if (failCnt > 2) {
      return false;
    }
  };

  /*Discover attributesをしないとサービスが見えてこない。*/
  if (peripheral.discoverAttributes()) {
  } else {
    peripheral.disconnect();
    return false;
  }
  /*サービスの取得*/
  if (peripheral.discoverService(ELINK_SERVICE_UUID)) {
    sElinkService = peripheral.service(ELINK_SERVICE_UUID);
  } else {
    peripheral.disconnect();
    return false;
  }
  /*Characteristic(1524)の取得*/
  if (sElinkService.hasCharacteristic(ELINK_CHARACTERISTIC_UUID)) {
    sElinkMotorCharacteristic = sElinkService.characteristic(ELINK_CHARACTERISTIC_UUID);
  }
  else {
    peripheral.disconnect();
    return false;
  }

  /*Characteristic(1525)の取得*/
  if (sElinkService.hasCharacteristic(ELINK_READCHARACTERISTIC_UUID)) {
    sElinkReadCharacteristic = sElinkService.characteristic(ELINK_READCHARACTERISTIC_UUID);
  }
  else {
    peripheral.disconnect();
    return false;
  }

  /*Elinkにおまじないコードを送る*/
  byte sendBytes[] = { 0xaa, 0xcf,0x00,0x00,0x5d,0x4a,0x81,0x89,0x32,0xf7,0x52,0x12,0x36,0x00,0x00,0x00,0x00,0x00};
  if(sElinkMotorCharacteristic.writeValue(sendBytes, sizeof(sendBytes))){
  }
  return true;
}

/*
*割り込み内でBLEのwrite処理を行うとCPUリセットがかかる
*/
void ISR_ShiftUp() {
  if(IsConnected){
    sGearChangePacket = 0x02U;
    sShiftChange = true;
  }
}
void ISR_ShiftDown() {
  if(IsConnected){
    sGearChangePacket = 0x03U;
    sShiftChange = true;
  }
}

void CpuSleep(){
  NRF_POWER->SYSTEMOFF = 1;
}

void timerReset(){
  sleepTimer = millis();
}

void timerCheck(unsigned long tick){
  unsigned long now = millis();
  unsigned long divTime = now - sleepTimer;
  if(divTime > tick){
    CpuSleep();  
  }
}

void setup() {
  digitalWrite(LED_PWR, LOW);

  pinMode(PIN_SHIFT_UP, INPUT_PULLUP);
  pinMode(PIN_SHIFT_DOWN, INPUT_PULLUP);
 
  attachInterrupt(digitalPinToInterrupt(PIN_SHIFT_UP),ISR_ShiftUp, FALLING);
  attachInterrupt(digitalPinToInterrupt(PIN_SHIFT_DOWN), ISR_ShiftDown, FALLING);

  // begin initialization
  if (!BLE.begin()) {
    while (1);
  }
  BLE.setConnectionInterval(0x0006, 0x0c80);

  // Elinkをスキャン
  BLE.scanForAddress(ELINK_MACADDRESS);

  timerReset();
}

void loop() {

  if (IsConnected == true ) {
    /*接続中*/
    delay(100);
    if(!sBLEPeripheral.connected()){
      /*通信切断されていた場合、再接続処理*/
      ELINK_DisConnect();
      return;
    }
    if(sShiftChange == true){
      timerReset();
      sShiftChange = false;
      while(!sElinkMotorCharacteristic.writeValue(sGearChangePacket, sizeof(sGearChangePacket))){
      }
    }
    timerCheck(SLEEP_ENTERTIME);
  } else {
    /*スキャン中*/
    ELINK_DuringScan();
    timerCheck(SLEEP_ENTERTIME_SEARCH);
  }
}

void ELINK_DuringScan() {
  BLEDevice peripheral = BLE.available();
  if (peripheral) {
    BLE.stopScan();/*スキャンをストップしてからConnectしないとConnectに高確率で失敗する*/
    if (!Elink_Connect(peripheral)) {
      /*接続に失敗したら再スキャン*/
      BLE.scanForAddress(ELINK_MACADDRESS);
    } else {
      /*接続完了*/
      IsConnected = true;
      sBLEPeripheral = peripheral;
      timerReset();
    }
  }
}

void ELINK_DisConnect() {
  IsConnected = false;
  BLE.scanForAddress(ELINK_MACADDRESS);
  timerReset();
}